*Telefonliste
#main
*-------------------------------------------------------------------------
* Variablen:
* Zeile     aktuelle Zeilenummer
* ZlMax     Zeile ab der der Fussbereich beginnt
* Seite     Seitennummer beginnend mit 1
* RandX     linker Rand in cm
* RandY     oberer Rand in cm
* SizeX     Druckbreite ab Rand links
* recMAIN   Datensatz fuer Main-Schleifen
*--------------------------------------------------------------------------
VAR RepTitel(C,50,0)
VAR Zeile(s,2,0)
VAR ZlMax(s,2,0)
VAR Seite(s,2,0)
VAR RandX(d,8,2)
VAR RandY(d,8,2)
VAR SizeX(d,8,2)
VAR Heute(D,10,0)
VAR cyZeile(d,8,3)
VAR mLPI(s,2,0)
VAR mSumme(d,8,2)
VAR mTop(L,1,0)

* Datensatz EIGENE_ANSCHRIFTEN
REC recADR(EIGENE_ANSCHRIFTEN,0,2)01

*-------------------------------------------------------------------------
* Prüfen der Übergabe von Filtervariablen

* Code für den
* Berichtsablauf ein.

SUB #subPaperDefs
REC recMAIN(KONTENPLAN,5,2)PL

*-----------------------------------------------------------------------------
* Vorbereiten der Ausgabe 
* Initialisierung der Drucksteuerdaten
OUT INITPAGESIZE
OUT STARTJOB $[RepTitel]
OUT TRANSPARENT
OUT STARTPAGE
Zeile=0
OUT ##KopfBericht
OUT ##KopfDetail
*-----------------------------------------------------------------------------

* Aufruf des Unterprogramms loopMAIN fuer jeden Datensatz
* der an recMAIN gebundenen Tabelle
LOOP recMAIN(#loopMAIN)

* ----------------------------------------------------
* Druckdatei abschliessen
Zeile=$[ZlMax]
OUT ##FussBericht
OUT ##outPost
OUT ENDPAGE
OUT ENDJOB


#end

##KopfBericht
CY=3
L=0;0;50;1;Times New Roman,10,N;$[recADR.NAME1] $[recADR.NAME2]
L=0;1;50;1;Times New Roman,10,N;$[recADR.STRASSE]
L=0,0;2,0;50,0;1,0;Times New Roman,10,N;$[recADR.PLZORT]
R=50;0;50;1;Times New Roman,10,F;$[RepTitel]
R=85;1;15;1;Times New Roman,10,N;$[Heute]
R=85;2;15;1;Times New Roman,10,N;Seite -$[Seite]-

#end

##KopfSeite
CY=3
L=0;0;50;1;Times New Roman,10,N;$[recADR.NAME1] $[recADR.NAME2]
L=0;1;50;1;Times New Roman,10,N;$[recADR.STRASSE]
L=0,0;2,0;50,0;1,0;Times New Roman,10,N;$[recADR.PLZORT]
R=50;0;50;1;Times New Roman,10,F;$[RepTitel]
R=85;1;15;1;Times New Roman,10,N;$[Heute]
R=85;2;15;1;Times New Roman,10,N;Seite -$[Seite]-

#end

##KopfDetail
CY=3
L=0;0;100;1; ;\-
L=0,0;1,0;10,0;1,0;Times New Roman,10,F;Konto
L=10,0;1,0;34,0;1,0;Times New Roman,10,F;Bezeichnung
L=64,0;1,0;12,0;1,0;Times New Roman,10,F;gebucht am
R=88,0;1,0;12,0;1,0;Times New Roman,10,F;Saldo
L=0;2;100;1; ;\-
R=76,0;1,0;12,0;1,0;Times New Roman,10,F;Umsatz
L=44,0;1,0;20,0;1,0;Times New Roman,10,F;Telefon

#end

##outUebertr
CY=1
R=88,0;0,0;12,0;1,0;Times New Roman,10,F;$[mSumme]
L=10,0;0,0;20,0;1,0;Arial,10,F;Summe Salden Übertrag

#end

#Kopf
* Dieser Code wird immer beim Seitenwchsel
* aufgerufen, um den Kopf der nächsten Seite
* auszugeben
* Der Kopf für die erste Seite steht jedoch
* im Codestück OnPreReport

Zeile=0
OUT ##KopfSeite
OUT ##KopfDetail
OUT ##outUebertr
mTop=1

#end

#Fuss
* Dieser Code wird immer beim Seitenwchsel
* aufgerufen, um den Fuss der aktuellen Seite
* auszugeben
* Der Fuss für die letzte Seite steht jedoch
* im Codestück OnPostReport

Zeile=$[ZlMax]
OUT ##FussSeite
OUT ##outPost
OUT ENDPAGE
Seite=$[Seite]+1
Zeile=0
OUT STARTPAGE

#end

#CheckPage
* Fussbereich ausgeben, wenn letzte Zeile erreicht
IF BOOL($[Zeile] >= $[ZlMax])
   SUB #Fuss
* Kopfbereich ausgeben, wenn erste Zeile erreicht
IF BOOL($[Zeile] = 0)
   SUB #Kopf

#end

#NeueSeite
* nächste Seite anfangen
SUB #Fuss
SUB #Kopf

#end

##outMAIN
CY=1
L=0,0;0,0;10,0;1,0;Arial,10,F;$[recMAIN.Konto]
L=10,0;0,0;34,0;1,0;Arial,10,N;$[recDEST.Name1]
R=88,0;0,0;12,0;1,0;Arial,10,F;$[cSaldo]
R=76,0;0,0;12,0;1,0;Arial,10,N;$[recSALD.SaldoUms]
L=64,0;0,0;12,0;1,0;Arial,10,N;$[recSALD.Tag].$[recSALD.Monat].$[recSALD.Jahr]
L=44,0;0,0;20,0;1,0;Arial,10,N;$[recDEST.Telefon1]

#end

##outLine
CY=1
L=0;0;100;1; ;\-

#end

##outLineFeed
CY=1

#end

##outDEST
* Ausgabe für ReportMain/loopMAIN/loopDEST
CY=1
L=10,0;0,0;34,0;1,0;Arial,10,N;$[recDEST.Name1]
L=44,0;0,0;20,0;1,0;Arial,10,N;$[recDEST.Telefon1]

#end

##outDESTtop
* Ausgabe für ReportMain/loopMAIN/loopDEST
CY=1
L=0,0;0,0;10,0;1,0;Arial,10,N;$[recMAIN.Konto]
L=10,0;0,0;34,0;1,0;Arial,10,N;$[recDEST.Name1]
L=44,0;0,0;20,0;1,0;Arial,10,N;$[recDEST.Telefon1]

#end

#loopDEST
* Unterprgramm von ReportMain/loopMAIN
* Datensatzschleife recDEST
SUB #CheckPage

IF BOOL(($[mTop]) <> (0))
  OUT ##outDESTtop
ELSE
  OUT ##outDEST

mTop=0
RETURN

#end

#loopMAIN
* Unterprogramm von ReportMain
* Datensatzschleife recMAIN

* letzten Buchungssatz holen
* -----------------------------------------------------------------------------
REC recSALD(BUCHUNGSZEILEN,100,9)$[recMAIN.Typ<1]$[recMAIN.Konto<8]
IF BOOL(($[recSALD.SaldoNeu]) = (0))
  RETURN

REC recDEST(ADRESSSTAMM,8,8)$[recMAIN.Konto<8]

VAR cSaldo(C,16,0)
VAR dSaldo(N,14,2)
dSaldo=0,00 - $[recSALD.SaldoNeu]
IF BOOL(($[recSALD.SaldoNeu]) < (0))
  cSaldo=$[dSaldo] S
ELSE
  cSaldo=$[recSALD.SaldoNeu] H

* Daten ausgeben
* -----------------------------------------------------------------------------
SUB #CheckPage
OUT ##outMAIN
mTop=0
mSumme= $[mSumme] - $[recSALD.SaldoNeu]

* Zugehörige Adressen ausgeben
IFNOT EOF(recDEST)
  SKIP recDEST
LOOP recDEST(#loopDEST)

RETURN

#end

##outPost
CY=2
L= 0;0;15;1;Arial,8,N;$[recADR.BANK1_NAME]  
L=15;0;35;1;Arial,8,N;(BLZ: $[recADR.BANK1_BLZ])  Kto-Nr. $[recADR.BANK1_KONT]
L=0,0;1,0;15,0;1,0;Arial,8,N;$[recADR.BANK2_NAME]
L=15;1;35;1;Arial,8,N;(BLZ: $[recADR.BANK2_BLZ])  Kto-Nr. $[recADR.BANK2_KONT]
L=50;0;15;1;Arial,8,N;Telefon
L=50;1;15;1;Arial,8,N;$[recADR.TELEFON]
L=65;0;15;1;Arial,8,N;Telefax
L=65,0;1,0;15,0;1,0;Arial,8,N;$[recADR.FAXNR]
R=80;0;20;1;Arial,8,N;E-Mail
R=80;1;20;1;Arial,8,N;$[recADR.NAME3]

#end

#subPaperDefs
* Definition des Basislayouts und Papiergrößen

* Zeilen per Inc
mLPI=6

RepTitel=Saldenliste Kreditoren
Heute=H
RandX=      1,80
RandY=      0,80
SizeX=      18,0
Seite=      1
Zeile=      0
cyZeile=    2.54/$[mLPI]
ZlMax=     61

RETURN

#end

##FussSeite
CY=3
L=0;0;100;1; ;\-
L=0;2;100;1; ;\-
R=88,0;1,0;12,0;1,0;Times New Roman,10,F;$[mSumme]
L=10,0;1,0;20,0;1,0;Arial,10,F;Summe Salden Übertrag
L=0,0;1,0;10,0;1,0;Arial, 8,N;Liste Nr. 1007

#end

##FussBericht
CY=3
L=0;0;100;1; ;\-
L=0;2;100;1; ;\-
R=88,0;1,0;12,0;1,0;Times New Roman,10,F;$[mSumme]
L=10,0;1,0;20,0;1,0;Arial,10,F;Summe Salden
L=0,0;1,0;10,0;1,0;Arial, 8,N;Liste Nr. 1007

#end

